Tracés de courbes

Certaines courbes mathématiques peuvent se tracer grâce à un mécanisme. En paramétrant ce mécanisme, on peut, grâce à MetaPost, générer les images d'un tel procédé. En les assemblant sous forme d'un petit «film» on obtient les animations que je présente ci-dessous.

MetaPost permet de générer des images SVG qu'il est possible d'animer grâce à une librairie Javascript que J.-M. Sarlat a développé et que l'on peut trouver ici : https://melusine.eu.org/syracuse/svg/.

J'ai réalisé une autre présentation de ces animations grâce à Flex d'Adobe. Il s'agit d'une application Flash. Le lien de l'animation : http://melusine.eu.org/syracuse-courbes/

Mes animations sont aussi en ligne sur le site syracuse.eu.org, avec de nombreuses autres que je vous invite à aller voir ici.

Une kiéroïde

Chargement...

Une kiéroïde

Considérons une droite \(\Delta\) d'équation \(y=a\). Soit un point \(P\) sur cette droite et le cercle de centre \(P\) et de rayon \(c\). On construit le point \(N\) comme étant à l'intersection du cercle et de la droite tangente au cercle d'équation \(y=a-c\). Nommons alors \(M\) l'intersection du cercle et de la droite \((ON)\) où \(O\) est l'origine. Lorsque \(P\) décrit la droite \(\Delta\), \(M\) décrit une Kiéroïde.

La construction que voici est un cas particulier de Kiéroïde, pour plus de généralité allez voir : http://www.mathcurve.com/courbes2d/kieroide/kieroide.shtml.


prologues := 3;
outputtemplate := "%j/%j-%c.svg";
outputformat := "svg";

verbatimtex
%&latex
\documentclass{minimal}
\usepackage[charter]{mathdesign}
\usepackage[utf8]{inputenc}
\begin{document}
etex

% l'unité graphique
u:=.7cm;

% paramètres
a:=-2u;
b:=-4u;
c:=abs(a-b); % rayon du cercle
largeurDroite:=12u;

% fonction(s)
def droite(expr a,b)=
  10[a,b]--10[b,a]
enddef;

def demiedroite(expr a,b)=
  0.01[a,b]--10[a,b]
enddef;

% les ensembles de construction
pair O;
O:=(0,0);
path supportCercle,  supportSegment, cercle,kieroide;

supportCercle:=(-largeurDroite,a)--(+largeurDroite,a);
supportSegment:=(-largeurDroite,b)--(+largeurDroite,b);
cercle:=fullcircle scaled (2*c);

% les constructions mouventes

pair P,N,M;
path  demieNO, cercleP;

for t:=0 step 0.005 until 1:
  i:=round(t*200);
  beginfig(i);
    % le point P parcours la droite supportCercle
    P:=point t of supportCercle;
    % cercle centré en P
    cercleP:=cercle shifted P;
    % M comme intersection
    N:=(xpart P,b);
    demieNO:=demiedroite(N,O);

    M:=demieNO intersectionpoint cercleP;

    %on définie la courbe
    if i=0:
      kieroide:=M;
    else:
      kieroide:=kieroide--M;
    fi;
    % on dessine
    draw supportCercle withcolor green dashed evenly withpen pencircle scaled 1pt;
    draw cercleP dashed evenly  withcolor (0.7,0.7,0.7)  withpen pencircle scaled 1pt;
    draw supportSegment dashed evenly  withcolor (0.7,0.7,0.7)  withpen pencircle scaled 1pt;
    draw N--O withcolor blue withpen pencircle scaled 1pt;
    draw N--P withcolor blue withpen pencircle scaled 1pt;
    draw M--P withcolor blue withpen pencircle scaled 1pt;
    draw kieroide withcolor red withpen pencircle scaled 1pt;
    % les labels
    dotlabel.bot(btex $P$ etex, P);
    dotlabel.bot(btex $M$ etex, M);
    dotlabel.bot(btex $N$ etex, N);
    dotlabel.bot(btex $O$ etex, O);
    label.ulft(btex $\mathcal C$ etex, P+(cosd(125)*c,sind(125)*c));
    label.bot(btex $\Delta$ etex, (8u,a));
    label(btex \itshape La Kiéroïde etex, (5u, u));
    clip currentpicture to (10u,-5u)--(-10u,-5u)--(-10u,2u)--(10u,2u)--cycle;
  endfig;
endfor;
end.

Tracés de courbes

Liste des courbes

Une kiéroïde